Clojure's odpowiednik kodowania Pythona ("hex") i dekodowania ("hex")

Question

Czy istnieje idiomatyczny sposób kodowania i dekodowania ciągu znaków w Clojure w postaci szesnastkowej? Przykład z Pythona:

'Clojure'.encode('hex') 
# ⇒ '436c6f6a757265' 
'436c6f6a757265'.decode('hex') 
# ⇒ 'Clojure' 

Aby pokazać trochę wysiłku z mojej strony:

(defn hexify [s] 
    (apply str 
    (map #(format "%02x" (int %)) s))) 

(defn unhexify [hex] 
    (apply str 
    (map 
     (fn [[x y]] (char (Integer/parseInt (str x y) 16))) 
     (partition 2 hex)))) 

(hexify "Clojure") 
;; ⇒ "436c6f6a757265" 

(unhexify "436c6f6a757265") 
;; ⇒ "Clojure" 

Answer 1

wierzę czynność unhexify jest idiomatyczne, jak to tylko możliwe. Jednak hexify mogą być napisane w prostszy sposób:

(defn hexify [s] 
    (format "%x" (new java.math.BigInteger (.getBytes s)))) 

Answer 2

Implementacja (s) nie działają dla znaków spoza ASCII,

(defn hexify [s] 
    (apply str 
    (map #(format "%02x" (int %)) s))) 

(defn unhexify [hex] 
    (apply str 
    (map 
     (fn [[x y]] (char (Integer/parseInt (str x y) 16))) 
     (partition 2 hex)))) 

(= "\u2195" (unhexify(hexify "\u2195"))) 
false ; should be true 

Aby temu zaradzić trzeba serializować bajtów ciąg znaków za pomocą wymaganego kodowania znaków, który może być wielobajtowy na znak.

Jest kilka "problemów" z tym.

• Pamiętaj, że wszystkie typy liczbowe są podpisane w JVM.
• Brak bajtu bez znaku.

W idiomatycznej java używałbyś niskiego bajtu liczby całkowitej i zamaskowałbyś go tak, gdziekolwiek go używałeś.

int intValue = 0x80; 
    byte byteValue = (byte)(intValue & 0xff); -- use only low byte 

    System.out.println("int:\t" + intValue); 
    System.out.println("byte:\t" + byteValue); 

    -- output: 
    -- int: 128 
    -- byte: -128 

clojure ma (unchecked-byte), aby skutecznie zrobić to samo.

Na przykład za pomocą UTF-8 można to zrobić:

(defn hexify [s] 
    (apply str (map #(format "%02x" %) (.getBytes s "UTF-8")))) 

(defn unhexify [s] 
    (let [bytes (into-array Byte/TYPE 
       (map (fn [[x y]] 
        (unchecked-byte (Integer/parseInt (str x y) 16))) 
         (partition 2 s)))] 
    (String. bytes "UTF-8"))) 

; with the above implementation: 

;=> (hexify "\u2195") 
"e28695" 
;=> (unhexify "e28695") 
"↕" 
;=> (= "\u2195" (unhexify (hexify "\u2195"))) 
true 

Answer 3

Ponieważ wszystkie wysłane rozwiązania mają pewne wady, dzielę mój własny:

(defn hexify "Convert byte sequence to hex string" [coll] 
    (let [hex [\0 \1 \2 \3 \4 \5 \6 \7 \8 \9 \a \b \c \d \e \f]] 
     (letfn [(hexify-byte [b] 
     (let [v (bit-and b 0xFF)] 
      [(hex (bit-shift-right v 4)) (hex (bit-and v 0x0F))]))] 
     (apply str (mapcat hexify-byte coll))))) 

(defn hexify-str [s] 
    (hexify (.getBytes s))) 

i

(defn unhexify "Convert hex string to byte sequence" [s] 
     (letfn [(unhexify-2 [c1 c2] 
       (unchecked-byte 
        (+ (bit-shift-left (Character/digit c1 16) 4) 
         (Character/digit c2 16))))] 
    (map #(apply unhexify-2 %) (partition 2 s)))) 

(defn unhexify-str [s] 
    (apply str (map char (unhexify s)))) 

Plusy:

• Wysokowydajne
• Generic strumienia bajtów < - konwersje> ciąg z wyspecjalizowanych owijarki
• Handling zerem w wyniku hex