Jaki jest właściwy sposób sprawdzenia, czy program Excel OLE jest dostępny?

Question

Muszę przetestować, czy mogę używać programu Excel OLE z mojego programu, ponieważ można go uruchomić na komputerach bez programu Excel. Próbki kodu w Internecie zakładają, że program Excel jest zainstalowany, ale co jeśli nie?

XLApp := CreateOleObject('Excel.Application'); 
try 
    // Hide Excel 
    XLApp.Visible := False; 
    // Open the Workbook 
    XLApp.Workbooks.Open(aPath); 
    ...snip... 
finally 
    // Quit Excel 
    if not VarIsEmpty(XLApp) then 
    begin 
    XLApp.Quit; 
    XLAPP := Unassigned; 
    end; 
end; 

Czy to byłby prawidłowy kod, aby sprawdzić, czy program Excel jest zainstalowany?

//Try to create Excel OLE 
try 
    XLApp := CreateOleObject('Excel.Application'); 
except 
    ShowMessage('Error opening Excel'); 
    Exit; 
end; 

Answer 1

Można użyć kodu w oparciu o Scalabium's tip sprawdzić czy Excel jest dostępna. Lub coś podobnego:

uses ComObj, ActiveX; 

function IsObjectAvailable(const ClassName: string): Boolean; 
var 
    ClassID: TCLSID; 
begin 
    Result := Succeeded(CLSIDFromProgID(PWideChar(WideString(ClassName)), 
    ClassID)); 
end; 

Można również sprawdzić, czy Excel jest uruchomiony za pomocą następującego kodu:

function IsObjectActive(const ClassName: string): Boolean; 
var 
    ClassID: TCLSID; 
    Unknown: IUnknown; 
begin 
    Result := False; 
    if Succeeded(CLSIDFromProgID(PWideChar(WideString(ClassName)), ClassID)) then 
    Result := Succeeded(GetActiveObject(ClassID, nil, Unknown)); 
end; 

a potem w jakiejś procedury lub zdarzenia:

procedure TForm1.Button1Click(Sender: TObject); 
begin 
    if IsObjectAvailable('Excel.Application') then 
    ShowMessage('Excel is available'); 
    if IsObjectActive('Excel.Application') then 
    ShowMessage('Excel is running'); 
end;