Rozpakuj folder w górę

Question

Próbuję zarchiwizować folder w VBScript i wygląda na to, że nie działa. Jestem pewien, że poprawnie tworzę plik nagłówkowy.

Tworzy rzeczywisty plik poprawnie, po prostu nie zip folder.

Ktoś ma jakieś pomysły:

Sub ArchiveFolder (folder) 

    Dim fso, wShell, sApp, zipFile 

    Set fso = CreateObject("Scripting.FileSystemObject") 
    Set wShell = CreateObject("WScript.Shell") 
    Set sApp = CreateObject("Shell.Application") 
    Set zipFile = fso.CreateTextFile(folder & ".zip") 

    ' Write zip file header. 
    zipFile.Write "PK" & Chr(5) & Chr(6) & String(18, 0) 
    zipFile.Close 

    sApp.NameSpace(folder & ".zip").CopyHere folder 

End Sub 

Answer 1

Odpowiedź znalazłem here. Magia znajduje się w ostatnim Do..Loop, gdzie skrypt czeka na wykonanie zadania przez Shell.

ArchiveFolder "sub\foo.zip", "..\baz" 

Sub ArchiveFolder (zipFile, sFolder) 

    With CreateObject("Scripting.FileSystemObject") 
     zipFile = .GetAbsolutePathName(zipFile) 
     sFolder = .GetAbsolutePathName(sFolder) 

     With .CreateTextFile(zipFile, True) 
      .Write Chr(80) & Chr(75) & Chr(5) & Chr(6) & String(18, chr(0)) 
     End With 
    End With 

    With CreateObject("Shell.Application") 
     .NameSpace(zipFile).CopyHere .NameSpace(sFolder).Items 

     Do Until .NameSpace(zipFile).Items.Count = _ 
       .NameSpace(sFolder).Items.Count 
      WScript.Sleep 1000 
     Loop 
    End With 

End Sub 

Answer 2

Sprawdź swój argument. folder musi być ścieżką do obiektu, który chcesz umieścić w pliku zip. Jeśli jest to obiekt folderu, musisz użyć folder.Path, ponieważ domyślną metodą obiektów folderów jest Name, a CopyHere nie może znaleźć obiektu z samą nazwą.

Można dodać kilka sprawozdań debugowania do swojej funkcji, aby sprawdzić, czy:

WScript.Echo TypeName(folder) 
If fso.FolderExists(folder) Then 
    WScript.Echo folder & " exists." 
Else 
    WScript.Echo folder & " doesn't exist." 
End If 

Answer 3

można nazwać zewnętrznego pliku zip poprzez% COMSPEC%

oShell.Run "%comspec% /c c:\windows\7za.exe a " & oFile &".zip " & oFile & " -tzip",,True

Źródło http://www.scriptlook.com/zip-large-files-in-a-directory-2/