Perl, przekonwertuj hasz na tablicę

Question

Jeśli mam skrót w Perlu, który zawiera pełne i sekwencyjne mapowania całkowite (tj. Wszystkie klucze od 0 do n są odwzorowane na coś, bez kluczy poza tym), czy istnieje sposób przekształcając to w tablicę?

Wiem, że mógłbym powtórzyć parami klucz/wartość i umieścić je w nowej tablicy, ale coś mówi mi, że powinien istnieć wbudowany sposób robienia tego.

Answer 1

Jeśli oryginalne źródło danych jest hash:

# first find the max key value, if you don't already know it: 
use List::Util 'max'; 
my $maxkey = max keys %hash; 

# get all the values, in order 
my @array = @hash{0 .. $maxkey}; 

Lub, jeśli oryginalne dane źródłem jest hashref:

my $maxkey = max keys %$hashref; 
my @array = @{$hashref}{0 .. $maxkey}; 

---

Łatwo to sprawdzić za pomocą tego przykładu:

my %hash; 
@hash{0 .. 9} = ('a' .. 'j'); 

# insert code from above, and then print the result... 
use Data::Dumper; 
print Dumper(\%hash); 
print Dumper(\@array); 

$VAR1 = { 
      '6' => 'g', 
      '3' => 'd', 
      '7' => 'h', 
      '9' => 'j', 
      '2' => 'c', 
      '8' => 'i', 
      '1' => 'b', 
      '4' => 'e', 
      '0' => 'a', 
      '5' => 'f' 
     }; 
$VAR1 = [ 
      'a', 
      'b', 
      'c', 
      'd', 
      'e', 
      'f', 
      'g', 
      'h', 
      'i', 
      'j' 
     ]; 

Answer 2

OK, to nie jest bardzo "wbudowane", ale działa. To także IMHO preferuje dowolne rozwiązanie z "sortowaniem", ponieważ jest szybsze.

map { $array[$_] = $hash{$_} } keys %hash; # Or use foreach instead of map 

W przeciwnym razie, mniej wydajne:

my @array = map { $hash{$_} } sort { $a<=>$b } keys %hash; 

Answer 3

To pozostawi klucze nie zostały zdefiniowane w %hashed_keys jak undef:

# if we're being nitpicky about when and how much memory 
# is allocated for the array (for run-time optimization): 
my @keys_arr = (undef) x scalar %hashed_keys; 

@keys_arr[(keys %hashed_keys)] = 
    @hashed_keys{(keys %hashed_keys)}; 

A jeśli używasz nazwy:

@{$keys_arr}[(keys %{$hashed_keys})] = 
    @{$hashed_keys}{(keys %{$hashed_keys})}; 

Lub, bardziej niebezpiecznie, ponieważ zakłada to, co mówisz, że jest prawdą (nie zawsze może to być prawda i błąd; Po prostu powiedzmy!):

@keys_arr = @hashed_keys{(sort {$a <=> $b} keys %hashed_keys)}; 

Ale to jest poza tym punktem. Jeśli są na początku indeksowane liczbami całkowitymi, dlaczego są teraz w haszymku?

Answer 4

Można wyodrębnić wszystkie wartości z tablicy asocjacyjnej z values funkcję:

my @vals = values %hash; 

Jeśli chcesz je w określonej kolejności, a następnie można umieścić przyciski w odpowiedniej kolejności, a następnie podjąć hash slice z że:

my @sorted_vals = @hash{sort { $a <=> $b } keys %hash}; 

Answer 5

Jak powiedział DVK, nie ma zbudowany w sposób, ale będzie to rade:

my @array = map {$hash{$_}} sort {$a <=> $b} keys %hash; 

lub to:

my @array; 

keys %hash; 

while (my ($k, $v) = each %hash) { 
    $array[$k] = $v 
} 

odniesienia, aby zobaczyć co jest szybsze, moje przypuszczenie byłoby sekund.

Answer 6

Perl nie zapewnia wbudowanego rozwiązania, aby rozwiązać problem.

Jeśli wiesz, że klucze obejmować konkretny zakres 0..N, można wykorzystać ten fakt:

my $n = keys(%hash) - 1; 
my @keys_and_values = map { $_ => $hash{$_} } 0 .. $n; 
my @just_values  = @hash{0 .. $n}; 

Answer 7

Łączenie FM „s i Ether” odpowiedziami s pozwala uniknąć definiowania inaczej niepotrzebnego skalarne:

my @array = @hash{ 0 .. $#{[ keys %hash ]} }; 

Schludny rzeczą jest to, że w przeciwieństwie do z podejściem scalar, działa powyżej, nawet w mało prawdopodobnym przypadku, gdy domyślny indeks pierwszego elementu, $[, jest niezerowy.

Oczywiście oznaczałoby to pisząc coś głupiego i ukrywane tak:

my @array = @hash{ $[ .. $#{[ keys %hash ]} }; # Not recommended 

Ale wtedy zawsze istnieje zdalnego szansa że ktoś musi go gdzieś (WinCE) ...

Answer 8

@a = @h{sort { $a <=> $b } keys %h}; 

Answer 9

$Hash_value = 
{ 
'54' => 'abc', 
'55' => 'def', 
'56' => 'test', 
}; 
while (my ($key,$value) = each %{$Hash_value}) 
{ 
print "\n $key > $value"; 
} 

Answer 10

Możemy napisać trochę czasu, jak poniżej:

$j =0; 
while(($a1,$b1)=each(%hash1)){ 
    $arr[$j][0] = $a1; 
    ($arr[$j][1],$arr[$j][2],$arr[$j][3],$arr[$j][4],$arr[$j][5],$arr[$j][6]) = values($b1); 
    $j++; 
} 

$ a1 zawiera klucz i $ b1 zawiera wartości W powyższym przykładzie mam Hash z tablicy, a tablica zawiera 6 elementów.

Answer 11

Prostym sposobem jest wykonanie @array = %hash

Przykładowo

my %hash = (
    "0" => "zero", 
    "1" => "one", 
    "2" => "two", 
    "3" => "three", 
    "4" => "four", 
    "5" => "five", 
    "6" => "six", 
    "7" => "seven", 
    "8" => "eight", 
    "9" => "nine", 
    "10" => "ten", 
); 

my @array = %hash; 

print "@array"; będzie następujący wynik,

3 trzy 9 dziewięć 5 pięć 8 osiem 2 dwa 4 cztery 1 jeden 10 dziesięć 7 siedem 0 zero 6 sześć