Jak wybrać wszystkie węzły główne lub wszystkie węzły potomne w VirtualStringTree?

Question

Chciałbym wybrać wszystkie węzły główne lub wszystkie węzły podrzędne (nie wszystkie węzły w widoku VirtualTreeView).
Próbowałem użyć tego kodu, aby zaznaczyć wszystkie węzły root:

procedure SelectAllRoots; 
var 
    Node: PVirtualNode; 
begin 
    Form1.VirtualStringTree1.BeginUpdate; 
    Node := Form1.VirtualStringTree1.GetFirst; 
    while True do 
    begin 
    if Node = nil then 
     Break; 
    if not (vsSelected in Node.States) then 
     Node.States := Node.States + [vsSelected]; 
    Node := Form1.VirtualStringTree1.GetNext(Node); 
    end; 
    Form1.VirtualStringTree1.EndUpdate; 
end; 

mogę powiedzieć, że to mała usterka. Wybór jest niekompletny lub utknął. Co ja robię źle ?

Edytuj:
Używam MultiSelection.

Answer 1

1. Wybierz wszystkie węzły root:

aby zaznaczyć wszystkie węzły korzeniowych, można skorzystać z następującej procedury:

procedure SelectRootNodes(AVirtualTree: TBaseVirtualTree); 
var 
    Node: PVirtualNode; 
begin 
    AVirtualTree.BeginUpdate; 
    try 
    Node := AVirtualTree.GetFirst; 
    while Assigned(Node) do 
    begin 
     AVirtualTree.Selected[Node] := True; 
     Node := AVirtualTree.GetNextSibling(Node); 
    end; 
    finally 
    AVirtualTree.EndUpdate; 
    end; 
end; 

2. Zaznacz wszystkie węzły podrzędne:

Aby wybrać wszystkie węzły podrzędne, niezależnie od poziomu, należy użyć polecenia Funkcja rsive wygląda następująco:

procedure SelectChildNodes(AVirtualTree: TBaseVirtualTree); 
var 
    Node: PVirtualNode; 

    procedure SelectSubNodes(ANode: PVirtualNode); 
    var 
    SubNode: PVirtualNode; 
    begin 
    SubNode := AVirtualTree.GetFirstChild(ANode); 
    while Assigned(SubNode) do 
    begin 
     SelectSubNodes(SubNode); 
     AVirtualTree.Selected[SubNode] := True; 
     SubNode := AVirtualTree.GetNextSibling(SubNode); 
    end; 
    end; 

begin 
    AVirtualTree.BeginUpdate; 
    try 
    Node := AVirtualTree.GetFirst; 
    while Assigned(Node) do 
    begin 
     SelectSubNodes(Node); 
     Node := AVirtualTree.GetNextSibling(Node); 
    end; 
    finally 
    AVirtualTree.EndUpdate; 
    end; 
end;