Perl readdir w celu

Question

Czy istnieje sposób na zagwarantowanie zamówienia z listy zwróconej przez readdir?

mam kod:

opendir(my $DIR, $src) or die "Error opening $src"; 

# Loop for each file in the directory 
while (my $file = readdir($DIR)) 
{ 
     print "$file\n"; 
} 

Ale powraca w kolejności losowej. Teraz wiem, że istnieje wiele rozwiązań za pomocą szybkiego wyszukiwania w Google, ale nie mogę znaleźć dokładnej kolejności potrzebnej. Zasadniczo chcę, aby foldery pojawiały się FIRST lub LAST, a nie pomiędzy plikami.

Na przykład teraz, czy mam strukturę folderu:

folder 
folder 
file1 
file2 
file3 

uzyskać wynik:

file2 
folder 
folder 
file1 
file3 

Kiedy naprawdę chcę:

folder 
folder 
file1 
file2 
file3 

czyli

file1 
file2 
file3 
folder 
folder 

Jakikolwiek sposób to osiągnąć?

Dzięki.

Answer 1

można sortować poprzez umieszczenie foldery, a następnie sortując pliku/dir nazwie

# $src pointing to folder open with opendir 
my @sorted_dir = 
    map $_->[0], 
    sort { 
    $a->[1] <=> $b->[1] 
     || 
    $a->[0] cmp $b->[0] 
    } 
    map [ $_, -f "$src/$_" ], 
    readdir($DIR); 

Choć podobny efekt można osiągnąć,

for my $file (sort { -f "$src/$a" <=> -f "$src/$b" } readdir($DIR)) { 
    print "$file\n"; 
} 

to wolniej i nieefektywne jak to częściej przechodzi do sprawdzania systemu plików, jeśli wpis w katalogu jest zwykłym plikiem.

Answer 2

Możesz użyć do tego celu sort, patrząc na każdy wpis na liście zwróconej przez readdir.

opendir(my $DIR, '.') or die "Error opening "; 

foreach my $file (sort { -d $a <=> -d $b } readdir($DIR)) { 
    print "$file\n"; 
} 

Da to foldery jako ostatnie.

Answer 3

Można użyć part z List::MoreUtils

#!/usr/bin/env perl 

use strict; 
use warnings; 

use List::MoreUtils 'part'; 

my $dir = shift || '.'; 

opendir my $dh, $dir or die "Cannot open $dir"; 

my ($files, $dirs) = part { -d } sort readdir $dh; 

print "$_\n" for @$files, @$dirs; 

Dla innego pomysłu, można spojrzeć na File::Next.

Answer 4

foreach (sort readdir $dh) {} działa dobrze dla mnie.

Na przykład:

opendir (my $DIR, "$dir") || die "Error while opening $dir: $!\n"; 

foreach my $dirFileName(sort readdir $DIR) 
{ 
     next if $dirFileName eq '.' or $dirFileName eq '..'; 
     print("fileName: $dirFileName ... \n"); 
}