Jak wydrukować adres pamięci listy w Haskell

Question

Uczę się, jak niektóre języki programowania przypisują pamięć do danych strukturalnych (w tym przypadku studiuję tablice).

tworzę tablicę, jak pokazano here w sekcji 3.

import Data.Array.IO 
arr <- newArray (1,10) 37 :: IO (IOArray Int Int) --Sets default to 37 

i co próbuję zrobić, to wydrukować adres każdego elementu w pamięci, coś takiego:

Array Start: <dec addr> | <hex addr> --Shows where the array itself is 
Array 1: <dec addr> | <hex addr> --Memory address of the first element 
Array 2: <dec addr> | <hex addr| --Memory address of the second element 

Problem, który mam, polega na tym, że nie wiem, jak uzyskać wartość adresu pamięci dla elementu w Haskell.

Czy istnieje funkcja podobna do funkcji Pythona id(object) lub object.object_id Ruby?

Answer 1

można użyć następującego fragmentu które pożyczonej od opakowania ghc-heap-view (zawiera również alternatywne rozwiązanie używając foreign import prim):

{-# LANGUAGE MagicHash, BangPatterns #-} 

import GHC.Exts 

-- A datatype that has the same layout as Word and so can be casted to it. 
data Ptr' a = Ptr' a 

-- Any is a type to which any type can be safely unsafeCoerced to. 
aToWord# :: Any -> Word# 
aToWord# a = let !mb = Ptr' a in case unsafeCoerce# mb :: Word of W# addr -> addr 

unsafeAddr :: a -> Int 
unsafeAddr a = I# (word2Int# (aToWord# (unsafeCoerce# a))) 

działa przy pierwszym owijaniu a wewnątrz Ptr' konstruktora, a następnie odlewanie Ptr' a do Word. Ponieważ pole a jest reprezentowane jako wskaźnik, wynikowe słowo zawiera teraz adres obiektu. Zwykłe zastrzeżenia zastosowanie: jest to niebezpieczne, GHC specyficzne, zrywa więzy przejrzystości itp

Testowanie:

main :: IO() 
main = do 
    arr <- newListArray (1,10) [1,2..] :: IO (IOArray Int Int) 
    a1 <- readArray arr 1 
    a2 <- readArray arr 2 
    a1' <- readArray arr 1 

    putStrLn $ "a1 : " ++ (show . unsafeAddr $! a1) 
    putStrLn $ "a1 : " ++ (show . unsafeAddr $! a1) 
    putStrLn $ "a2 : " ++ (show . unsafeAddr $! a2) 
    putStrLn $ "a2 : " ++ (show . unsafeAddr $! a2) 
    putStrLn $ "a1': " ++ (show . unsafeAddr $! a1') 

wyjściowa:

a1 : 16785657 
a1 : 16785657 
a2 : 16785709 
a2 : 16785709 
a1': 16785657 

Zauważ, że należy użyć unsafeAddr z $!, w przeciwnym razie otrzymasz adres stroju, który oceni się jako a zamiast samego obiektu a:

let a = 1 
     b = 2 
     c = a + b 

    putStrLn $ "c: " ++ (show . unsafeAddr $ c) 
    putStrLn $ "c: " ++ (show . unsafeAddr $! c) 
    putStrLn $ "c: " ++ (show . unsafeAddr $! c) 

wyjściowa:

c: 9465024 
c: 9467001 
c: 9467001