oświadczenia przełącznika w Prologu

Question

W predykatów Prologu, często pisać powtarzające instrukcje warunkowe jak ten, ale szkoda, że ​​nie mógł być napisany bardziej zwięźle:

output(Lang, Type, Output) :- 
    (Lang = javascript -> 
     Output = ["function", Type]; 
    Lang = ruby -> 
     Output = ["def", Type]; 
    Lang = java -> 
     Output = [Type]). 

Czy byłoby możliwe, aby zastąpić tę serię instrukcji warunkowych z bardziej zwięzłe oświadczenie przełączające?

Answer 1

W Prologu jest to dość łatwe do zdefiniowania własnych struktur sterujących, za pomocą meta-orzeczników (predykatów, które mają cele lub predykatów jako argumenty).

Na przykład, można zaimplementować przełącznik skonstruować jak

switch(X, [ 
    a : writeln(case1), 
    b : writeln(case2), 
    c : writeln(case3) 
]) 

definiując

switch(X, [Val:Goal|Cases]) :- 
    (X=Val -> 
     call(Goal) 
    ; 
     switch(X, Cases) 
    ). 

jeśli to konieczne, to można wtedy osiągnąć poprzez transformację kompilacji jako obsługiwany przez wiele Prolog systemy (inline/2 w ECLiPSe lub rozszerzenie celu w kilku innych systemach).

Dzięki deklaracjom operatora można dostosować składnię do niemal wszystkiego, co się podoba.

Answer 2

nieco krótszy:

output(Lang, Type, Output) :- 
    (Lang, Output) = (javascript, ["function", Type]) ; 
    (Lang, Output) = (ruby, ["def", Type]) ; 
    (Lang, Output) = (java, [Type]). 

idiomatyczne:

output(Lang, Type, Output) :- 
    memberchk(Lang-Output, [ 
    javascript - ["function", Type], 
    ruby - ["def", Type], 
    java - [Type] 
    ]). 

Answer 3

Wydaje się, że wiele klauzul są wykonane w tym przypadku zastosowania, a także dość zwięzłe.

output(javascript, Type, ["javascript", Type]). 
output(ruby, Type, ["def", Type]). 
output(java, Type, [Type]).