Jak obliczyć liczbę dni roboczych między dwiema datami?

Question

Muszę obliczyć liczbę dni roboczych (dni roboczych) między dwiema podanymi datami. Dniami roboczymi są wszystkie dni tygodnia z wyjątkiem sobót i niedziel. Nie liczę wakacji w tej liczbie.

Jak obliczyć liczbę dni roboczych między dwiema datami?

Answer 1

Należy użyć DayOfTheWeek (z jednostki DateUtils) i licznika, iterując od daty początkowej do daty końcowej. (Będziesz także prawdopodobnie trzeba tabelę świąt, aby wykluczyć tych, z liczbą też.)

function BusinessDaysBetween(const StartDate, EndDate: TDateTime): Integer; 
var 
    CurrDate : TDateTime; 
begin 
    CurrDate := StartDate; 
    Result := 0; 
    while (CurrDate <= EndDate) do 
    begin 
    // DayOfTheWeek returns 1-5 for Mon-Fri, so 6 and 7 are weekends 
    if DayOfTheWeek(CurrDate) < 6 then 
     Inc(Result); 
    CurrDate := CurrDate + 1; 
    end; 
end; 

można poprawić ten mały, nie martwiąc się o kolejności parametrów (innymi słowy, nie robi „t znaczenia, jeśli start jest przed koniec lub koniec jest przed rozpoczęciem, funkcja będzie nadal działać):

function BusinessDaysBetween(const FirstDate, SecondDate: TDateTime): Integer; 
var 
    CurrDate : TDateTime; 
    StartDate, EndDate: TDateTime; 
begin 
    if SecondDate > FirstDate then 
    begin 
    StartDate := FirstDate; 
    EndDate := SecondDate; 
    end 
    else 
    begin 
    StartDate := SecondDate; 
    EndDate := FirstDate; 
    end; 

    CurrDate := StartDate; 
    Result := 0; 

    while (CurrDate <= EndDate) do 
    begin 
    if DayOfTheWeek(CurrDate) < 6 then 
     Inc(Result); 
    CurrDate := CurrDate + 1; 
    end; 
end; 

Answer 2

Bez pętli wszystkie dni i parametry wejściowe nie w zależności od zamówienia.

Uses DateUtils,Math; 

function WorkingDaysBetween(const firstDate,secondDate : TDateTime) : Integer; 
var 
    startDate,stopDate : TDateTime; 
    startDow,stopDow : Integer; 
begin 
    if (firstDate < secondDate) then 
    begin 
    startDate := firstDate; 
    stopDate := secondDate; 
    end 
    else 
    begin 
    startDate := secondDate; 
    stopDate := firstDate; 
    end; 
    startDow := DayOfTheWeek(startDate); 
    stopDow := DayOfTheWeek(stopDate); 
    if (stopDow >= startDow) then 
    stopDow := Min(stopDow,6) 
    else 
    Inc(stopDow,5); 

    Result := 
    5*WeeksBetween(stopDate,startDate) + 
    (stopDow - Min(startDow,6)); 
end; 

Answer 3

function BusinessDaysSinceFixedDate (const nDate : tDateTime) : integer; 
const 
    Map : array [ -6 .. 6 ] of integer 
     = ( 0, 0, 1, 2, 3, 4, 5, 5, 5, 6, 7, 8, 9); 
var 
    X : integer; 
begin 
    X := trunc (nDate); 
    Result := 5 * (X div 7) + Map [ X mod 7 ]; 
end; 

function BusinessDaysBetweenDates (const nStartDate : tDateTime; 
            const nEndDate : tDateTime) : integer; 
begin 
    Result := BusinessDaysSinceFixedDate (nEndDate) 
      - BusinessDaysSinceFixedDate (nStartDate); 
end; 

Rutynowe BusinessDaysSinceFixedDate oblicza liczbę dni roboczych od ustalonej daty. Konkretna data, która jest nieistotna, to poniedziałek, 25 grudnia, 1899. Po prostu liczy liczbę tygodni, które minęły (X div 7) i mnoży ją przez 5. Następnie dodaje przesunięcie do poprawienia w oparciu o dzień tygodnia. Zauważ, że (X mod 7) zwróci wartość ujemną dla negatywnej terminie, to znaczy przed datą 30 grudnia 1899.

Rutynowe BusinessDaysBetweenDates prostu wywołuje BusinessDaysSinceFixedDate do daty rozpoczęcia i zakończenia oraz odejmuje jeden od drugiego.