podprocedura skryptu wsadowego: przekazywanie argumentów

Question

Rozumiem, że aby uzyskać datę z pliku przekazanego do podprogramu jako argumentu, należy ustawić ten argument jako zmienną w podprogramie. Czy to jest poprawne? To mi nie wychodzi, więc zastanawiam się, czy nie w pełni rozumiem, co się dzieje. Mogę użyć przekazanego argumentu w praktycznie każdym innym podprogramie kodu, oprócz ekstrakcji daty.

set setupEXE=setup.exe 

CALL :SUB_CheckCorrectDate %setupEXE% 
GOTO EOF 
::---------------------------------- 

:SUB_CheckCorrectDate 
set filename=%1% 

:: SUCCESSFUL 
for %%x in (%filename%) do set FileDate=%%~tx 
@For /F "tokens=1-3 delims=-/ " %%A in ('@echo %FileDate%') do @( 
Set file_Month=%%A 
Set file_Day=%%B 
Set file_Year=%%C 
) 

:: GET ERROR  
for %%x in (%1%) do set FileDate=%%~tx 
@For /F "tokens=1-3 delims=-/ " %%A in ('@echo %FileDate%') do @( 
Set file_Month=%%A 
Set file_Day=%%B 
Set file_Year=%%C 
)  

GOTO:EOF 

:: ------------------ 
:EOF 

Answer 1

Zastosowanie %1 aby uzyskać dostęp do parametru, a nie %i%.

Zmienne argumentów mają takie same modyfikatory jak zmienne FOR, więc można użyć %~t1.

Nie trzeba wykonywać polecenia w FOR/F. Łatwiej jest przetwarzać ciąg literału za pomocą in ("string").

Nie jest wymagana etykieta :EOF. Każdy skrypt ma domyślny :eof. Lubię używać zamiast tego exit /b.

@echo off 
setlocal 
set "setupEXE=setup.exe" 

call :SUB_CheckCorrectDate "%setupEXE%" 
exit /b 

::---------------------------------- 

:SUB_CheckCorrectDate 
set "filename=%~1" 
for /F "tokens=1-3 delims=-/ " %%A in ("%~t1") do ( 
    set "file_Month=%%A" 
    set "file_Day=%%B" 
    set "file_Year=%%C" 
) 
exit /b 

Answer 2

jeśli poważnie chcą pisać skrypty wsadowe, należy zadbać o składni:

@echo off &setlocal 
set "setupEXE=setup.exe" 

CALL :SUB_CheckCorrectDate "%setupEXE%" 
GOTO EOF 
::---------------------------------- 

:SUB_CheckCorrectDate 
set "filename=%~1" 

:: SUCCESSFUL 
for %%x in ("%filename%") do set "FileDate=%%~tx" 
For /F "tokens=1-3 delims=-/ " %%A in ("%FileDate%") do ( 
    Set "file_Month=%%A" 
    Set "file_Day=%%B" 
    Set "file_Year=%%C" 
) 

:: GET ERROR  
for %%x in ("%~1") do set "FileDate=%%~tx" 
For /F "tokens=1-3 delims=-/ " %%A in ("%FileDate%") do ( 
    Set "file_Month=%%A" 
    Set "file_Day=%%B" 
    Set "file_Year=%%C" 
)  

GOTO:EOF 

:: ------------------ 
: