Jak wyświetlić typ zmiennej w PL/SQL?

Question

Czy istnieje funkcja PL/SQL wyświetlająca dokładny typ zmiennej, np. Funkcja DUMP w SQL?

Próbowałem następujące

DECLARE 
    l_variable INTEGER := 1; 
BEGIN 
    DBMS_OUTPUT.PUT_LINE (DUMP (l_variable)); 
END; 

Ale daje następujący błąd:

PLS-00204: function or pseudo-column 'DUMP' may be used inside a SQL statement only

Answer 1

Możesz utworzyć tę funkcję przy użyciu PL/Scope. Ale nie zadziała z anonimowymi blokami i będziesz musiał odwoływać się do zmiennej jako łańcucha znaków.

create or replace function get_plsql_type_name 
(
    p_object_name varchar2, 
    p_name varchar2 
) return varchar2 is 
    v_type_name varchar2(4000); 
begin 
    select reference.name into v_type_name 
    from user_identifiers declaration 
    join user_identifiers reference 
     on declaration.usage_id = reference.usage_context_id 
     and declaration.object_name = reference.object_name 
    where 
     declaration.object_name = p_object_name 
     and declaration.usage = 'DECLARATION' 
     and reference.usage = 'REFERENCE' 
     and declaration.name = p_name; 

    return v_type_name; 
end; 
/

Przykład:

alter session set plscope_settings = 'IDENTIFIERS:ALL'; 

create or replace type my_weird_type is object 
(
    a number 
); 

create or replace procedure test_procedure is 
    var1 number; 
    var2 integer; 
    var3 my_weird_type; 
    subtype my_subtype is pls_integer range 42 .. 43; 
    var4 my_subtype; 
begin 
    dbms_output.put_line(get_plsql_type_name('TEST_PROCEDURE', 'VAR1')); 
    dbms_output.put_line(get_plsql_type_name('TEST_PROCEDURE', 'VAR2')); 
    dbms_output.put_line(get_plsql_type_name('TEST_PROCEDURE', 'VAR3')); 
    dbms_output.put_line(get_plsql_type_name('TEST_PROCEDURE', 'VAR4')); 
end; 
/

begin 
    test_procedure; 
end; 
/

NUMBER 
INTEGER 
MY_WEIRD_TYPE 
MY_SUBTYPE 

Answer 2

declare 
    a number(10,3); 
    type_info varchar2(400); 
begin 
    a := 55.5; 
    select dump(a) into type_info from dual; 
    DBMS_OUTPUT.PUT_LINE(type_info); 
end; 

Answer 3

jak należy zauważyć, NORA jest przeciążony funkcji. ma 3 przeciążenia.

Możesz symulować to samo w swoim kodzie.

function myDump (x Varchar2) return varchar2 is begin return('string') ; end ; 
function myDump (x number) return varchar2 is begin return('integer') ; end ; 
function myDump (x date) return varchar2 is begin return('date') ; end ; 

Powyższy kod może nie działać poprawnie, ale powinien dać Ci pomysł rozwiązania problemu.

Mam nadzieję, że spełni to Twoje wymagania.

Uwaga; możesz umieścić te funkcje w Pakiecie i użyć ich odpowiednio.