PureScript Halogen i websockets

Question

Próbuję użyć purescript-halogen w połączeniu z websockets, ale po kilku próbach nie jestem w stanie zmusić ich do współpracy.

Widziałem this question on Thermite and websockets i odpowiedź Phila na temat funkcji Driver. Halogen ma również funkcję Driver, ale muszę uruchomić funkcję Driver z efektem Aff, a purescript-websockets-simple wykorzystuje efekt Eff.

Nie mam pojęcia, jak przekształcić synchroniczne wywołania zwrotne z pakietu websocket do asynchronicznego kodu działającego w monadzie Aff. Czy muszę korzystać z AVar? Czy potrzebuję purescript-coroutines-aff? Jeśli tak, w jaki sposób mogę połączyć te części razem?

Z góry dziękuję za wszelkie wskazówki we właściwym kierunku!

Answer 1

W tym przypadku naprawdę chciałbyś użyć purescript-aff-coroutines. Że będzie Ci współprogram Producer które można następnie podłączyć do Consumer że popycha wiadomości do kierowcy:

module Main where 

import Prelude 

import Control.Coroutine (Producer, Consumer, consumer, runProcess, ($$)) 
import Control.Coroutine.Aff (produce) 
import Control.Monad.Aff (Aff) 
import Control.Monad.Aff.AVar (AVAR) 
import Control.Monad.Eff (Eff) 
import Control.Monad.Eff.Exception (EXCEPTION) 
import Control.Monad.Eff.Var (($=)) 

import Data.Array as Array 
import Data.Either (Either(..)) 
import Data.Maybe (Maybe(..)) 

import Halogen as H 
import Halogen.HTML.Indexed as HH 
import Halogen.Util (runHalogenAff, awaitBody) 

import WebSocket (WEBSOCKET, Connection(..), Message(..), URL(..), runMessageEvent, runMessage, newWebSocket) 

---------------------------------------------------------------------------- 
-- Halogen component. This just displays a list of messages and has a query 
-- to accept new messages. 
---------------------------------------------------------------------------- 

type State = { messages :: Array String } 

initialState :: State 
initialState = { messages: [] } 

data Query a = AddMessage String a 

ui :: forall g. H.Component State Query g 
ui = H.component { render, eval } 
    where 
    render :: State -> H.ComponentHTML Query 
    render state = 
    HH.ol_ $ map (\msg -> HH.li_ [ HH.text msg ]) state.messages 

    eval :: Query ~> H.ComponentDSL State Query g 
    eval (AddMessage msg next) = do 
    H.modify \st -> { messages: st.messages `Array.snoc` msg } 
    pure next 

---------------------------------------------------------------------------- 
-- Websocket coroutine producer. This uses `purescript-aff-coroutines` to 
-- create a producer of messages from a websocket. 
---------------------------------------------------------------------------- 

wsProducer :: forall eff. Producer String (Aff (avar :: AVAR, err :: EXCEPTION, ws :: WEBSOCKET | eff)) Unit 
wsProducer = produce \emit -> do 
    Connection socket <- newWebSocket (URL "ws://echo.websocket.org") [] 

    -- This part is probably unnecessary in the real world, but it gives us 
    -- some messages to consume when using the echo service 
    socket.onopen $= \event -> do 
    socket.send (Message "hello") 
    socket.send (Message "something") 
    socket.send (Message "goodbye") 

    socket.onmessage $= \event -> do 
    emit $ Left $ runMessage (runMessageEvent event) 

---------------------------------------------------------------------------- 
-- Coroutine consumer. This accepts a Halogen driver function and sends 
-- `AddMessage` queries in when the coroutine consumes an input. 
---------------------------------------------------------------------------- 

wsConsumer 
    :: forall eff 
    . (Query ~> Aff (H.HalogenEffects (ws :: WEBSOCKET | eff))) 
    -> Consumer String (Aff (H.HalogenEffects (ws :: WEBSOCKET | eff))) Unit 
wsConsumer driver = consumer \msg -> do 
    driver $ H.action $ AddMessage msg 
    pure Nothing 

---------------------------------------------------------------------------- 
-- Normal Halogen-style `main`, the only addition is a use of `runProcess` 
-- to connect the producer and consumer and start sending messages to the 
-- Halogen component. 
---------------------------------------------------------------------------- 

main :: forall eff. Eff (H.HalogenEffects (ws :: WEBSOCKET | eff)) Unit 
main = runHalogenAff do 
    body <- awaitBody 
    driver <- H.runUI ui initialState body 
    runProcess (wsProducer $$ wsConsumer driver) 
    pure unit 

To powinno dać stronę, która niemal natychmiast drukuje:

1. powitania
2. coś
3. pożegnanie

Ale robi kiedykolwiek wszystko, czego potrzebujesz, szczerze! Jeśli użyjesz producenta z "prawdziwym" źródłem, dostaniesz coś bardziej podobnego do tego, czego potrzebujesz.