Pobierz wszystkie pliki cookie z przeglądarki Internet Explorer

Question

Próbuję pobrać wszystkie pliki cookie powiązane z konkretną stroną, którą mam otwarty (już uwierzytelniono). Z tą stroną powiązano kilka plików cookie. Muszę pobrać każdy plik cookie, aby później wykonać test POST.

Próbowałem kilku podejść, ale żaden nie dał mi pełnej listy. Napisałem kod do tej pory w języku VBA, ale nie przeszkadza mi też jego obecność w .NET.

Pierwsza próba, po uzyskaniu wskaźnika do IE.

arraycookie = Split(ie.document.Cookie, ";") 

For i = LBound(arraycookie) To UBound(arraycookie) 
    Debug.Print arraycookie(i) 
Next i 

Daje mi to niektóre z plików cookie, ale nie wszystkie z nich. Mogę przejrzeć pliki cookie w narzędziach programistycznych (F12) i potwierdziłem, że żadne ciasteczka nie mają znacznika HTTP. Zobacz zdjęcie poniżej.

Próbowałem też Windows API InternetGetCookie. Zwraca plik cookie, ale tylko jeden i jest taki sam bez względu na nazwę (np. FedAuth poniżej).

Private Sub GetCookieAttempt() 
Dim sCookieVal As String * 256 
Dim bRet As Boolean 
bRet = InternetGetCookie("https://mywebsiteaddresshere.com", _ 
    "FedAuth", sCookieVal, 255) 
    If bRet = False Then 
     MsgBox "Failed" 
    Else 
     MsgBox sCookieVal 
    End If 
End Sub 

To tylko odgadnięcie (jakikolwiek pomysł, jak się dowiedzieć?), Ale z tego co przeczytałem może wynikać, że plik cookie jest chroniony. Przyjrzałem się interfejsowi API IEGetProtectedModeCookie, ale nie mogłem go uzyskać, aby zwrócić informacje o plikach cookie.

Nie wiem, dlaczego mogę to zobaczyć za pomocą narzędzi programistycznych, ale kiedy próbuję i ujawnić informacje, nie zwraca wszystko.

Każda pomoc byłaby bardzo ceniona :)

Dzięki!

---

Edit

Więc po kopanie wokół tej kwestii pomyślałem, że spróbować samą stronę z innej przeglądarce i ponownie sprawdź szczegóły cookie.

Używanie ciasteczek Firebug, które próbowałem pobrać, pokazuje teraz flagę HTTPOnly. Z tego co rozumiem, mogę użyć InternetGetCookieEx z podaną flagą INTERNET_COOKIE_HTTPONLY. Jednak nie mogę go odzyskać.

Czy ktoś ma działającą próbkę, którą mogę śledzić?

Answer 1

Spróbuj pobrać pliki cookie IE z folderu shell:cookies. Jest poniższy kod jako przykład:

Option Explicit 

Sub GetIECookies() 

    Dim sCookiesPath As String 
    Dim oCookies As Object 
    Dim oFSO As Object 
    Dim oFolder As Object 
    Dim oFile 
    Dim sContent As String 
    Dim a() As String 
    Dim i As Long 
    Dim aItems 
    Dim aCookies() 

    ' read IE cookie files 
    sCookiesPath = CreateObject("shell.application").Namespace("shell:Cookies").self.Path 
    Set oCookies = CreateObject("Scripting.Dictionary") 
    Set oFSO = CreateObject("Scripting.FileSystemObject") 
    Set oFolder = oFSO.GetFolder(sCookiesPath) 
    For Each oFile In oFolder.Files 
     If LCase(oFSO.GetExtensionName(oFile.Name)) = "txt" Then 
      With oFile.OpenAsTextStream(1, 0) ' read-only, ascii 
       sContent = .ReadAll 
       .Close 
      End With 
      sContent = Replace(sContent, vbCr, "") 
      ' split cookies within file 
      a = Split(sContent, vbLf & "*" & vbLf) 
      For i = 0 To UBound(a) - 1 
       oCookies.Add oCookies.Count, a(i) 
      Next 
     End If 
    Next 
    ' parse data, repack to 2d array 
    aItems = oCookies.Items() 
    If UBound(aItems) = -1 Then 
     MsgBox "No cookies found" 
    Else 
     ReDim aCookies(1 To UBound(aItems) + 1, 1 To 6) 
     For i = 1 To UBound(aItems) + 1 
      a = Split(aItems(i - 1), vbLf) 
      aCookies(i, 1) = a(0) 
      aCookies(i, 2) = a(1) 
      aCookies(i, 3) = a(2) 
      aCookies(i, 4) = GetInetCookieFlags(a(3)) 
      aCookies(i, 5) = ConvDT(a(4), a(5)) 
      aCookies(i, 6) = ConvDT(a(6), a(7)) 
     Next 
     ' output 
     With ThisWorkbook.Sheets(1) 
      .Cells.Delete 
      .Range("A1:F1") = Array("Name", "Value", "Host/Path", "Flags", "Expiration", "Created") 
      Output .Range("A2"), aCookies 
     End With 
    End If 

End Sub 

Function ConvDT(sLowNTFmt As String, sHighNTFmt As String) As Date 

    Dim dNTFmt As Double 
    Dim dUnixFmt As Double 

    ' FILETIME format is the number of 100 nanosecond ticks since 00:00 1 Jan, 1601 (UTC). 
    dNTFmt = sHighNTFmt * 4294967296# + sLowNTFmt 
    ' Unix time format is the number of seconds since 00:00 1 Jan 1970 
    dUnixFmt = 0.0000001 * dNTFmt - 11644473600# 
    ' VB time format is the number of days since 00:00 1 Jan 1900 
    ConvDT = CDate(dUnixFmt/86400 + 25569) 

End Function 

Function GetInetCookieFlags(sFlags As String) As String 

    Dim lFlags As Long 
    Dim aFlag 

    ' reset bit 32 to avoid overflow 
    If sFlags >= 2147483648# Then lFlags = CLng(sFlags - 2147483648#) Else lFlags = CLng(sFlags) 
    ' convert flags bits to string representation 
    With CreateObject("Scripting.Dictionary") 
     For Each aFlag In Array(_ 
      Array(&H1, "IS SECURE"), _ 
      Array(&H2, "IS SESSION"), _ 
      Array(&H10, "THIRD PARTY"), _ 
      Array(&H20, "PROMPT REQUIRED"), _ 
      Array(&H40, "EVALUATE P3P"), _ 
      Array(&H80, "APPLY P3P"), _ 
      Array(&H100, "P3P ENABLED"), _ 
      Array(&H200, "IS RESTRICTED"), _ 
      Array(&H400, "IE6"), _ 
      Array(&H800, "IS LEGACY"), _ 
      Array(&H1000, "NON SCRIPT"), _ 
      Array(&H2000, "HTTPONLY"), _ 
      Array(&H4000, "HOST ONLY"), _ 
      Array(&H8000, "APPLY HOST ONLY"), _ 
      Array(&H20000, "RESTRICTED ZONE"), _ 
      Array(&H20000000, "ALL COOKIES"), _ 
      Array(&H40000000, "NO CALLBACK"), _ 
      Array(&H80000000, "ECTX 3RDPARTY") _ 
     ) 
      If lFlags And aFlag(0) Then .Add .Count, aFlag(1) 
     Next 
     GetInetCookieFlags = Join(.Items(), vbCrLf) 
    End With 

End Function 

Sub Output(oDstRng As Range, aCells As Variant) 

    With oDstRng 
     .Parent.Select 
     With .Resize(_ 
      UBound(aCells, 1) - LBound(aCells, 1) + 1, _ 
      UBound(aCells, 2) - LBound(aCells, 2) + 1 _ 
     ) 
      .NumberFormat = "@" 
      .Value = aCells 
      .Columns.AutoFit 
     End With 
    End With 

End Sub 

Wyjście dla mnie po usunięciu wszystkich plików cookie i przechodząc do https://stackoverflow.com/ się następująco:

Kilka uwag dotyczących kodu.

Parsuje pliki tylko w katalogu Cookies\, ale nie w Cookies\Low\, który jest przeznaczony dla aplikacji działających z niskimi uprawnieniami. Pobiera trwałe pliki cookie przechowywane tylko w folderze, ale nie pliki cookie sesji, które są przechowywane w pamięci i są dostępne tylko w procesie, który je utworzył. Czas jest w UTC.

Struktura cookie w pliku jest następująca:

Cookie name 
Cookie value 
Host/path for the web server setting the cookie 
Flags 
Exirpation time (low) 
Expiration time (high) 
Creation time (low) 
Creation time (high) 
Record delimiter (*) 

Flagi są zdefiniowane zgodnie wininet.dll headers:

#define INTERNET_COOKIE_IS_SECURE    0x00000001 
#define INTERNET_COOKIE_IS_SESSION    0x00000002 
#define INTERNET_COOKIE_THIRD_PARTY    0x00000010 
#define INTERNET_COOKIE_PROMPT_REQUIRED   0x00000020 
#define INTERNET_COOKIE_EVALUATE_P3P    0x00000040 
#define INTERNET_COOKIE_APPLY_P3P    0x00000080 
#define INTERNET_COOKIE_P3P_ENABLED    0x00000100 
#define INTERNET_COOKIE_IS_RESTRICTED   0x00000200 
#define INTERNET_COOKIE_IE6      0x00000400 
#define INTERNET_COOKIE_IS_LEGACY    0x00000800 
#define INTERNET_COOKIE_NON_SCRIPT    0x00001000 
#define INTERNET_COOKIE_HTTPONLY     0x00002000 
#define INTERNET_COOKIE_HOST_ONLY    0x00004000 
#define INTERNET_COOKIE_APPLY_HOST_ONLY   0x00008000 
#define INTERNET_COOKIE_RESTRICTED_ZONE   0x00020000 
#define INTERNET_COOKIE_ALL_COOKIES    0x20000000 
#define INTERNET_COOKIE_NO_CALLBACK    0x40000000 
#define INTERNET_COOKIE_ECTX_3RDPARTY   0x80000000