katalog Otwórz Eksploratora Windows, wybrać konkretny plik (w Delphi)

Question

Mam procedurę, aby otworzyć folder w Eksploratorze Windows, która jest przekazywana ścieżkę katalogu:

procedure TfrmAbout.ShowFolder(strFolder: string); 
begin 
    ShellExecute(Application.Handle,PChar('explore'),PChar(strFolder),nil,nil,SW_SHOWNORMAL); 
end; 

Czy istnieje sposób również przekazać to na nazwa pliku (pełna ścieżka do nazwy pliku lub tylko nazwa + rozszerzenie) i czy folder jest otwarty w Eksploratorze Windows, ale także czy jest zaznaczony/wybrany? Lokalizacja, którą mam zamiar, ma wiele plików i muszę wtedy manipulować tym plikiem w systemie Windows.

Answer 1

Tak, można użyć /select flag kiedy zadzwonić explorer.exe:

ShellExecute(0, nil, 'explorer.exe', '/select,C:\WINDOWS\explorer.exe', nil, 
    SW_SHOWNORMAL) 

Nieco bardziej wyszukane (i prawdopodobnie również bardziej wiarygodne) podejście (uses ShellAPI, ShlObj):

const 
    OFASI_EDIT = $0001; 
    OFASI_OPENDESKTOP = $0002; 

{$IFDEF UNICODE} 
function ILCreateFromPath(pszPath: PChar): PItemIDList stdcall; external shell32 
    name 'ILCreateFromPathW'; 
{$ELSE} 
function ILCreateFromPath(pszPath: PChar): PItemIDList stdcall; external shell32 
    name 'ILCreateFromPathA'; 
{$ENDIF} 
procedure ILFree(pidl: PItemIDList) stdcall; external shell32; 
function SHOpenFolderAndSelectItems(pidlFolder: PItemIDList; cidl: Cardinal; 
    apidl: pointer; dwFlags: DWORD): HRESULT; stdcall; external shell32; 

function OpenFolderAndSelectFile(const FileName: string): boolean; 
var 
    IIDL: PItemIDList; 
begin 
    result := false; 
    IIDL := ILCreateFromPath(PChar(FileName)); 
    if IIDL <> nil then 
    try 
     result := SHOpenFolderAndSelectItems(IIDL, 0, nil, 0) = S_OK; 
    finally 
     ILFree(IIDL); 
    end; 
end;