Jak wysłać dane dotyczące postów i nagłówków za pomocą Chromium?

Question

Próbuję przekonwertować kod z TWebBrowser na Chromium, ale mam problem z ustaleniem sposobu wysyłania danych postów i nagłówków za pomocą żądania HTTP.

Poniżej znajduje się funkcja TWebBrowser, którą próbuję zaimplementować.

var 
VHeader, PostData: OleVariant; 


PostData := VarArrayCreate([0, Length(XMLString) - 1], varByte) ;  
HeaderData := 'Content-Type: application/x-www-form-urlencoded'+ '\n'; 

WebBrowser1.Navigate(StrUrl,EmptyParam,EmptyParam,PostData,VHeader); 

Jak zrobić ekwiwalent z chromem?

Answer 1

Z powodu braku dokumentacji dla Delphi Chromium Embedded, odniosę się do potrzebnych wymagań dotyczących wysyłania żądań internetowych dla wersji C++ C++. Musisz więc użyć metody LoadRequest do wysyłania żądań w Chromium. Aby go użyć, potrzebna jest instancja obiektu klasy obiektu żądania żądania CefRequest wraz z obiektami HeaderMap i CefPostData dla nagłówka żądania i specyfikacji danych.

Rozszerzając Henri Gourvest za (autor owijki Delphi CEF) przykład z this thread można w Delphi spróbować czegoś podobnego poniższym pseudo-kod:

uses 
    ceflib; 

function CreateField(const AValue: AnsiString): ICefPostDataElement; 
begin 
    Result := TCefPostDataElementRef.New; 
    Result.SetToBytes(Length(AValue), PAnsiChar(AValue)); 
end; 

procedure TForm1.Button1Click(Sender: TObject); 
var 
    Header: ICefStringMultimap; 
    Data: ICefPostData; 
    Request: ICefRequest; 
begin 
    Header := TCefStringMultimapOwn.Create; 
    Header.Append('Content-Type', 'application/x-www-form-urlencoded'); 

    Data := TCefPostDataRef.New; 
    Data.AddElement(CreateField('Data.id=27')); 
    Data.AddElement(CreateField('&Data.title=title')); 
    Data.AddElement(CreateField('&Data.body=body')); 

    Request := TCefRequestRef.New; 
    Request.Flags := WUR_FLAG_NONE; 
    Request.Assign('http://example.com/', 'POST', Data, Header); 

    Chromium1.Browser.MainFrame.LoadRequest(Request); 
end; 

To samo należy zrobić kolejną wersję powyższego kodu :

procedure TForm1.Button1Click(Sender: TObject); 
var 
    Header: ICefStringMultimap; 
    Data: ICefPostData; 
    Request: ICefRequest; 
begin 
    Request := TCefRequestRef.New; 
    Request.Url := 'http://example.com/'; 
    Request.Method := 'POST'; 
    Request.Flags := WUR_FLAG_NONE; 

    Header := TCefStringMultimapOwn.Create; 
    Header.Append('Content-Type', 'application/x-www-form-urlencoded'); 
    Request.SetHeaderMap(Header); 

    Data := TCefPostDataRef.New; 
    Data.AddElement(CreateField('Data.id=27')); 
    Data.AddElement(CreateField('&Data.title=title')); 
    Data.AddElement(CreateField('&Data.body=body')); 
    Request.PostData := Data; 

    Chromium1.Browser.MainFrame.LoadRequest(Request); 
end;