Jak wysyłką zdarzenie z dodatkowymi danymi - AS3

Question

Może ktoś dać mi prosty przykład jak wysyłką zdarzenie w ActionScript3 z obiektem z nim związane, jak

dispatchEvent(new Event(GOT_RESULT,result)); 

Tutaj result jest obiektem Chcę przekazać wraz z wydarzeniem.

Answer 1

Jeśli chcesz przekazać obiekt przez wydarzenie, powinieneś utworzyć zdarzenie niestandardowe. Kod powinien być podobny do tego.

public class MyEvent extends Event 
{ 
    public static const GOT_RESULT:String = "gotResult"; 

    // this is the object you want to pass through your event. 
    public var result:Object; 

    public function MyEvent(type:String, result:Object, bubbles:Boolean=false, cancelable:Boolean=false) 
    { 
     super(type, bubbles, cancelable); 
     this.result = result; 
    } 

    // always create a clone() method for events in case you want to redispatch them. 
    public override function clone():Event 
    { 
     return new MyEvent(type, result, bubbles, cancelable); 
    } 
} 

Następnie można użyć powyższy kod tak:

dispatchEvent(new MyEvent(MyEvent.GOT_RESULT, result)); 

I nasłuchiwać tego zdarzenia w miarę potrzeby.

addEventListener(MyEvent.GOT_RESULT, myEventHandler); 
// more code to follow here... 
protected function myEventHandler(event:MyEvent):void 
{ 
    var myResult:Object = event.result; // this is how you use the event's property. 
} 

Answer 2

Jeśli jest właściwie zaprojektowany, nie powinno się przekazywać obiektu na to wydarzenie.
Zamiast tego powinieneś publicznie zmienić klasę wysyłkową.

public var myObject:Object; 

// before you dispatch the event assign the object to your class var 
myObject = ....// whatever it is your want to pass 
// When you dispatch an event you can do it with already created events or like Tomislav wrote and create a custom class. 

// in the call back just use currentTarget 
public function myCallBackFunction(event:Event):void{ 

    // typecast the event target object 
    var myClass:myClassThatDispatchedtheEvent = event.currentTarget as myClassThatDispatchedtheEvent 
    trace(myClass.myObject)// the object or var you want from the dispatching class. 

Answer 3

Ten post jest trochę stary, ale jeśli to może pomóc komuś, można użyć klasy DataEvent tak:

dispatchEvent(new DataEvent(YOUR_EVENT_ID, true, false, data)); 

Documentation