Jak wysłać powiadomienie o zwarciu po kompilacji potoku Jenkins?

Question

Mam skrypt groovy rurociągu w Jenkins v2.19. Mam również
"Powiadomienie o zalewaniu" v2.0.1 i "Groovy Postbuild Plugin".

Udało mi się wysłać wiadomość "build started" i "build finished" (jeśli miał).

Kiedy nie udało się wykonać jakiegoś kroku kompilacji - w jaki sposób mogę wysłać komunikat "Kompilacja nie powiodła się" do kanału Slack?

Answer 1

Możesz zrobić coś takiego i użyć bloku catch próby.

Oto przykład kodu:

node { 
    try { 
     notifyBuild('STARTED') 

     stage('Prepare code') { 
      echo 'do checkout stuff' 
     } 

     stage('Testing') { 
      echo 'Testing' 
      echo 'Testing - publish coverage results' 
     } 

     stage('Staging') { 
      echo 'Deploy Stage' 
     } 

     stage('Deploy') { 
      echo 'Deploy - Backend' 
      echo 'Deploy - Frontend' 
     } 

    } catch (e) { 
    // If there was an exception thrown, the build failed 
    currentBuild.result = "FAILED" 
    throw e 
    } finally { 
    // Success or failure, always send notifications 
    notifyBuild(currentBuild.result) 
    } 
} 

def notifyBuild(String buildStatus = 'STARTED') { 
    // build status of null means successful 
    buildStatus = buildStatus ?: 'SUCCESSFUL' 

    // Default values 
    def colorName = 'RED' 
    def colorCode = '#FF0000' 
    def subject = "${buildStatus}: Job '${env.JOB_NAME} [${env.BUILD_NUMBER}]'" 
    def summary = "${subject} (${env.BUILD_URL})" 

    // Override default values based on build status 
    if (buildStatus == 'STARTED') { 
    color = 'YELLOW' 
    colorCode = '#FFFF00' 
    } else if (buildStatus == 'SUCCESSFUL') { 
    color = 'GREEN' 
    colorCode = '#00FF00' 
    } else { 
    color = 'RED' 
    colorCode = '#FF0000' 
    } 

    // Send notifications 
    slackSend (color: colorCode, message: summary) 
} 

Kompletna fragment można znaleźć tutaj Jenkinsfile Template

Answer 2

podstawie Liam Newman's blog post, spojrzeć na tym fragmencie czyszczone tylko za Slack. Wykorzystuje oryginalne Jenkins results formatowanie wiadomość, lepsze kolory (na podstawie EclEmma), a niektóre Groovy funkcje, takie jak default arguments:

def notifySlack(String buildStatus = 'STARTED') { 
    // Build status of null means success. 
    buildStatus = buildStatus ?: 'SUCCESS' 

    def color 

    if (buildStatus == 'STARTED') { 
     color = '#D4DADF' 
    } else if (buildStatus == 'SUCCESS') { 
     color = '#BDFFC3' 
    } else if (buildStatus == 'UNSTABLE') { 
     color = '#FFFE89' 
    } else { 
     color = '#FF9FA1' 
    } 

    def msg = "${buildStatus}: `${env.JOB_NAME}` #${env.BUILD_NUMBER}:\n${env.BUILD_URL}" 

    slackSend(color: color, message: msg) 
} 

node { 
    try { 
     notifySlack() 

     // Existing build steps. 
    } catch (e) { 
     currentBuild.result = 'FAILURE' 
     throw e 
    } finally { 
     notifySlack(currentBuild.result) 
    } 
} 

Wyjście będzie coś takiego (poeksperymentować z różnymi stylami formatowania here):

może env.JOB_NAME zawiera zakodowane ukośnik (%2F), które mogą być ustalone z replaceAll("%2F", "/").

Sprawdź, jak powiadomić HipChat, jak również this Gist.