Jak zmienić odcień tekstury za pomocą GLSL?

Question

Czy istnieje sposób, aby skutecznie zmienić odcień tekstury 2D OpenGL za pomocą GLSL (fragment shader)?

Czy ktoś ma jakiś kod?

UPDATE: Jest to kod wynikające z user1118321 sugestia:

uniform sampler2DRect texture; 
const mat3 rgb2yiq = mat3(0.299, 0.587, 0.114, 0.595716, -0.274453, -0.321263, 0.211456, -0.522591, 0.311135); 
const mat3 yiq2rgb = mat3(1.0, 0.9563, 0.6210, 1.0, -0.2721, -0.6474, 1.0, -1.1070, 1.7046); 
uniform float hue; 

void main() { 

vec3 yColor = rgb2yiq * texture2DRect(texture, gl_TexCoord[0].st).rgb; 

float originalHue = atan(yColor.b, yColor.g); 
float finalHue = originalHue + hue; 

float chroma = sqrt(yColor.b*yColor.b+yColor.g*yColor.g); 

vec3 yFinalColor = vec3(yColor.r, chroma * cos(finalHue), chroma * sin(finalHue)); 
gl_FragColor = vec4(yiq2rgb*yFinalColor, 1.0); 
} 

I to jest wynik w porównaniu z wzorcem:

próbowałem przełączyć ja z Q wewnątrz atan, ale wynik jest nieprawidłowy nawet około 0 °

Masz jakaś podpowiedź?

Jeśli potrzebne dla porównania, jest to oryginalny obraz niemodyfikowana:

Answer 1

Choć co @awoodland mówi jest poprawna, że ​​metoda może powodować problemy ze zmianami w luminancji, wierzę.

Systemy kolorów HSV i HLS są problematyczne z wielu powodów. Ostatnio rozmawiałem o tym z naukowcem zajmującym się kolorystyką, a jego rekomendacją było przekonwertowanie do przestrzeni YIQ lub YCbCr i dostosowanie kanałów chroma (I & Q lub Cb & Cr) odpowiednio. (Można dowiedzieć się, jak zrobić to here i here.)

Gdy w jednym z tych miejsc, można uzyskać odcień od kąta utworzonego przez kanały chroma, wykonując hue = atan(cr/cb) (oglądając dla cb == 0). Daje to wartość w radianach. Po prostu obróć go, dodając wielkość obrotu barwy. Gdy to zrobisz, możesz obliczyć wielkość barwy za pomocą chroma = sqrt(cr*cr+cb*cb). Aby powrócić do RGB, obliczyć nowe Cb i Cr (lub I & Q) przy użyciu Cr = chroma * sin (hue), . Następnie przekonwertuj z powrotem na RGB zgodnie z opisem na powyższych stronach internetowych.

EDYCJA: Oto rozwiązanie, które przetestowałem i wydaje mi się, że daje takie same wyniki, jak Twoje odniesienie. Prawdopodobnie można zwinąć niektóre iloczyn skalarny w mnoży macierzy:

uniform sampler2DRect inputTexture; 
uniform float hueAdjust; 
void main() 
{ 
    const vec4 kRGBToYPrime = vec4 (0.299, 0.587, 0.114, 0.0); 
    const vec4 kRGBToI  = vec4 (0.596, -0.275, -0.321, 0.0); 
    const vec4 kRGBToQ  = vec4 (0.212, -0.523, 0.311, 0.0); 

    const vec4 kYIQToR = vec4 (1.0, 0.956, 0.621, 0.0); 
    const vec4 kYIQToG = vec4 (1.0, -0.272, -0.647, 0.0); 
    const vec4 kYIQToB = vec4 (1.0, -1.107, 1.704, 0.0); 

    // Sample the input pixel 
    vec4 color = texture2DRect (inputTexture, gl_TexCoord [ 0 ].xy); 

    // Convert to YIQ 
    float YPrime = dot (color, kRGBToYPrime); 
    float I  = dot (color, kRGBToI); 
    float Q  = dot (color, kRGBToQ); 

    // Calculate the hue and chroma 
    float hue  = atan (Q, I); 
    float chroma = sqrt (I * I + Q * Q); 

    // Make the user's adjustments 
    hue += hueAdjust; 

    // Convert back to YIQ 
    Q = chroma * sin (hue); 
    I = chroma * cos (hue); 

    // Convert back to RGB 
    vec4 yIQ = vec4 (YPrime, I, Q, 0.0); 
    color.r = dot (yIQ, kYIQToR); 
    color.g = dot (yIQ, kYIQToG); 
    color.b = dot (yIQ, kYIQToB); 

    // Save the result 
    gl_FragColor = color; 
} 

Answer 2

Andrea3000, porównując przykłady YIQ w internecie, natknąłem się na komentarz, ale myślę, że jest problem z wersją „zaktualizowanego” z Twój kod .... jestem pewien, że twoje definicje 'mat3' są odwrócone/flopped na kolejność kolumn/rzędów ... (być może dlatego nadal masz kłopoty) ...

FYI: Zamawianie macierzy OpenGL : "W przypadku większej liczby macierzy są wypełniane w porządku kolumna-większa, tzn. Pierwsze wartości X są pierwszą kolumną, drugą wartością X jest następna kolumna itd." Zobacz: http://www.opengl.org/wiki/GLSL_Types

mat2(
float, float, //first column 
float, float); //second column