WYBÓR w pętli FOR - Windows Batch

Question

Mam tę pętlę, która powtarza się dla każdej linii w zewnętrznym pliku. Chciałbym poprosić użytkownika o wybór w każdym przebiegu, ale to nie działa. Sądzę, że problem polega na tym, że polecenie GOTO w jakiś sposób przerywa pętlę. Jakieś przemyślenia na ten temat?

FOR /F %%i IN (%WORKDIR%\grunt-packages.ini) DO (
    CHOICE /C AN /M "Odinstalovat plugin" 
    IF %ERRORLEVEL%==1 GOTO UNINSTALL 
    IF %ERRORLEVEL%==2 GOTO SKIP 

    :UNINSTALL 
     ECHO Odstranuji %%i 
     CALL npm uninstall %%i 

    :SKIP 
     ECHO Preskakuji %%i 
) 

Answer 1

Twoje rozliczenie jest poprawne. goto w ciągu pętli przerwie pętlę. Aby obejść to, należy zamiast tego użyć call. Jednak pierwszym problemem z twoim skryptem jest potrzeba opóźnionego rozszerzenia dla zmiennej ERRORLEVEL. Kiedykolwiek rozwijasz zmienne, które są ustawione w zakresie nawiasów, użyj opóźnionego rozwinięcia, aby uzyskać najnowszą wartość.

SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION 
FOR /F %%i IN (%WORKDIR%\grunt-packages.ini) DO (
    CHOICE /C AN /M "Odinstalovat plugin" 
    IF !ERRORLEVEL!==1 CALL :UNINSTALL 
    IF !ERRORLEVEL!==2 CALL :SKIP 
) 
ENDLOCAL 
GOTO :EOF 

:UNINSTALL 
    ECHO Odstranuji %%i 
    CALL npm uninstall %%i 
    GOTO :EOF 

:SKIP 
    ECHO Preskakuji %%i 
    GOTO :EOF 

1. gotonie może być używany w for pętli.
2. Zmienne ustawione w nawiasach wymagają opóźnionego rozwinięcia w celu pobrania nowej wartości. ! zamiast %. W przeciwnym razie zostanie użyta wartość zmiennej przed zakresem nawiasów.

Answer 2

@ Odpowiedź Metzgera była dobrym początkiem (przegłosowałem go), ale znalazłem kilka problemów z tym. Na koniec wolę umieścić kod w linii i ominąć numer CALLs. Oto mój kod test, aby pokazać jak to się robi:

@echo off 
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION 
FOR %%i IN (A B C D) DO (
    CHOICE /C AN /M "Uninstall plugin %%i" 
    IF !ERRORLEVEL!==1 (
     ECHO Uninstall %%i 
    ) ELSE IF !ERRORLEVEL!==2 (
     ECHO Skip %%i 
    ) 
) 

Testowałem @ odpowiedź Metzgera w systemie Windows XP i stwierdzili, że następujące zagadnienia:

• Podprogramy brakujących GOTO :EOF (już na stałe)
• W systemie Windows XP w podprogramów %%i jest ustawiona
• (Potential bug) Jeśli odinstalować ustawia ERRORLEVEL, SKIP można nazwać

Ten kod testu rozwiązuje problemy:

@echo off 
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION 
FOR %%i IN (A B C D) DO (
    CHOICE /C AN /M "Uninstall plugin %%i" 
    SET OERRORLEVEL=!ERRORLEVEL! 
    IF !ERRORLEVEL!==1 CALL :UNINSTALL %%i 
    IF !OERRORLEVEL!==2 CALL :SKIP %%i 
) 
ENDLOCAL 
GOTO :EOF 

:UNINSTALL 
    ECHO Uninstall %1 
    GOTO :EOF 

:SKIP 
    ECHO Skip %1 
    GOTO :EOF 

Answer 3

Struktura ta pozwala uniknąć stosowania DELAYEDEXPANSION

@ECHO OFF 
SETLOCAL 
FOR %%i IN (A B C D) DO (
SET destcall=BADCHOICE 
choice /c QJ /M "%%i - choose Q or J" 
IF ERRORLEVEL 1 SET destcall=CHOSEQ 
IF ERRORLEVEL 2 SET destcall=CHOSEJ 
CALL CALL :%%destcall%% 
) 
GOTO :eof 

:badchoice 
ECHO bad choice 
GOTO :eof 

:choseq 
ECHO You chose Q 
GOTO :eof 

:chosej 
ECHO You chose J 
GOTO :eof