Wykryj, czy Debugger jest dołączony do VB6

Question

Wykonuję pewne prace konserwacyjne na jednej z naszych starych aplikacji napisanych w języku Visual Basic 6, i z różnych powodów mamy część kodu, która musi zostać uruchomiona tylko jeśli uruchamiamy program za pośrednictwem IDE VB6 (tj. dołączony jest debugger).

W VB.NET można to zrobić za pomocą właściwości System.Diagnostics.Debugger.IsAttached(), ale nie mogę znaleźć niczego podobnego w VB6 w Google.

Czy istnieje prosty sposób na wyodrębnienie tej informacji?

Answer 1

Oto funkcja Używam:

Private Function RunningInIde() As Boolean 
    On Error GoTo ErrHandler 
    Debug.Print 1/0 
ErrHandler: 
    RunningInIde = (Err.Number <> 0) 
End Function   ' RunningInIde 

Answer 2

Oto co używamy, że nie ma żadnych skutków ubocznych

Public Property Get InIde() As Boolean 
    Debug.Assert pvSetTrue(InIde) 
End Property 

Private Function pvSetTrue(bValue As Boolean) As Boolean 
    bValue = True 
    pvSetTrue = True 
End Function 

Answer 3

napisałem coś takiego jakiś czas temu i może” t znaleźć i potrzebował tego ponownie. Więc po prostu napisał to jeszcze raz i myślę, że miał rację:

Public Function IsRunningInIde() As Boolean 
    Static bFlag As Boolean 
    bFlag = Not bFlag 
    If bFlag Then Debug.Assert IsRunningInIde() 
    IsRunningInIde = Not bFlag 
    bFlag = False 
End Function 

Brak błędów coraz podniesiony.

Brak resetowania błędu.

Tylko jedna funkcja.

Wiersz 1: "Statyczna" deklaracja "bFlag" powoduje, że wartość bFlag polega na wielokrotnym wywołaniu "IsRunningInIde". Chcemy tego, ponieważ nazywam tę funkcję w sobie i nie chciałem zaśmiecać funkcji parametrami wejściowymi, które nie są potrzebne użytkownikowi.

Wiersz 3: "Debug.Assert" nie zostaje wywołany, gdy nie działa w środowisku IDE. Tak więc tylko w IDE "IsrunningInIde" jest wywoływany rekurencyjnie.

Wiersz 2: Jeśli nie w wywołaniu rekursywnym, bFlag rozpoczyna się od fałszu i otrzymuje wartość true. Jeśli w wywołaniu rekursywnym (dzieje się to tylko podczas działania w IDE), zaczyna się jako prawda i zostaje przywrócona wartość false.

Linia 3: wywoływać tylko "IsRunningInIde", jeśli nie jest jeszcze w tej funkcji rekurencyjnie, sprawdzając, czy bFlag ma wartość true.

Wiersz 4: Jeśli w wywołaniu rekurencyjnym, zawsze zwraca True, co nie ma znaczenia, ale nie powoduje niepowodzenia testu. Jeśli nie w wywołaniu rekursywnym, zwraca "Nie bFlag", który bFlag jest teraz "Fałsz", jeśli IsRunningInIde został nazwany rekursywnie, a bFlag jest "Prawdziwy", jeśli nie jest wywołany rekursywnie. Zasadniczo, nie bFlag zwraca "True", jeśli działa w IDE.

Linia 5: Czyści bFlag, aby zawsze był "fałszywy" na początku następnego połączenia z tą funkcją.

Trudno wytłumaczyć, lepiej jest przejść przez to w głowie, w obu scenariuszach.

Jeśli chcesz łatwiej zrozumieć kod, nie używaj go.

Jeśli wystąpi problem z tym kodem, przepraszam i daj mi znać, abym mógł to naprawić.

Answer 4

To jest moja funkcja, podobna do tej z Josha, ale łatwiejsza do odczytania (patrz komentarze wewnątrz).

użyłem go tak długo, że zapomniałem gdzie ja pożyczyłem od ...

Public Function InDesign() As Boolean 
' Returns TRUE if in VB6 IDE 
Static CallCount As Integer 
Static Res   As Boolean 

    CallCount = CallCount + 1 
    Select Case CallCount 
    Case 1 ' Called for the 1st time 
     Debug.Assert InDesign() 
    Case 2 ' Called for the 2nd time: that means Debug.Assert 
      ' has been executed, so we're in the IDE 
     Res = True 
    End Select 
    ' When Debug.Assert has been called, the function returns True 
    ' in order to prevent the code execution from breaking 
    InDesign = Res 

    ' Reset for further calls 
    CallCount = 0 

End Function 

Answer 5

Public Function InIDE() As Boolean 
On Error GoTo ErrHandler 

    Debug.Print 1 \ 0 'If compiled, this line will not be present, so we immediately get into the next line without any speed loss 

    InIDE = False 

Exit Function 
ErrHandler: 
InIDE = True 'We'll get here if we're in the IDE because the IDE will try to output "Debug.Print 1 \ 0" (which of course raises an error). 
End Function