SAS - Jak uzyskać ostatnie "n" obserwacji z zestawu danych?

Question

W jaki sposób można utworzyć zestaw danych SAS z innego zestawu danych przy użyciu tylko ostatnich n obserwacji z oryginalnego zestawu danych. Jest to łatwe, gdy znasz wartość n. Jeśli nie wiem "n", jak to zrobić?

Answer 1

Zakłada to, że posiadasz zmienną makro, która określa, ile obserwacji chcesz wykonać. NOBS informuje cię o liczbie obserwacji w zbiorze danych bez czytania całej treści.

%let obswant=5; 
data want; 
set sashelp.class nobs=obscount; 
if _n_ gt (obscount-&obswant.); 
run; 

Answer 2

Korzystanie przykład Joe zmiennej makro, aby określić liczbę obserwacji chcesz, tutaj jest inna odpowiedź:

%let obswant = 10; 
data want; 
    do _i_=nobs-(&obswant-1) to nobs; 
     set have point=_i_ nobs=nobs; 
     output; 
     end; 
    stop; /* Needed to stop data step */ 
run; 

ten powinien wykonać lepiej, gdyż tylko czyta konkretne obserwacje chcesz.

Answer 3

Dla odmiany, oto kolejny podejście (niekoniecznie lepszego)

%let obswant=5; 

proc sql noprint; 
select nlobs-&obswant.+1 into :obscalc 
from dictionary.tables 
where libname='SASHELP' and upcase(memname)='CLASS'; 
quit; 

data want; 
set sashelp.class (firstobs=&obscalc.); 
run; 

Answer 4

Jeśli zestaw danych jest duża, możesz nie chcieć, aby przeczytać cały zestaw danych. Zamiast tego możesz wypróbować konstrukcję, która najpierw odczyta całkowitą liczbę obserwacji w zbiorze danych. Więc jeśli chcesz mieć ostatnie spostrzeżenia:

data t; 
    input x; 
datalines; 
1 
2 
3 
4 
; 

%let dsid=%sysfunc(open(t)); 
%let num=%sysfunc(attrn(&dsid,nlobs)); 
%let rc=%sysfunc(close(&dsid)); 
%let number = 2; 

data tt; 
set t (firstobs = %eval(&num.-&number.+1)); 
run;