Jak wyprowadzać liczby całkowite za pomocą metody Put_Line?

Question

Nie mogę skompilować tego programu, ponieważ nie wydaje się on drukować zmiennych całkowitych razem z ciągami w metodzie Put_Line. Sprawdziłem kod źródłowy online i działa on, gdy robią to, gdzie jestem źle. Dzięki za pomoc.

with Ada.Text_IO;      use Ada.Text_IO; 
with Ada.Integer_Text_IO;   use Ada.Integer_Text_IO; 

procedure MultiplicationTable is 

    procedure Print_Multiplication_Table(Number :in Integer; Multiple :in Integer) is 
     Result : Integer; 
    begin 
     for Count in 1 ..Multiple 
     loop 
      Result := Number * Count; 
      Put_Line(Number & " x " & Count & " = " & Result); 
     end loop; 
    end Print_Multiplication_Table; 
    Number : Integer; 
    Multiple : Integer; 

begin 
    Put("Display the multiplication of number: "); 
    Get(Number); 
    Put("Display Multiplication until number: "); 
    Get(Multiple); 
    Print_Multiplication_Table(Number,Multiple); 
end MultiplicationTable;` 

Answer 1

Problem polega na tym, że używasz & z łańcuchów i liczb. Spróbuj wykonać jedną z następujących czynności:

Wymień Number wewnątrz parametru wpuść z Integer'Image(Number)

Albo zerwać Put_Line do komponentów, które chcesz; ex:

-- Correction to Put_Line(Number & " x " & Count & " = " & Result); 
Put(Number); 
Put(" x "); 
Put(Count); 
Put(" = "); 
Put(Result); 
New_Line(1); 

Answer 2

Spróbuj tego:

Put_Line(Integer'Image(Number) & " x " & Integer'Image(Count) & " = " & Integer'Image(Result)); 

Answer 3

Jesteś już with i use klauzule dla Ada.Integer_Text_IO, ale nie jesteś rzeczywiście go używać.

Zmień to:

Put_Line(Number & " x " & Count & " = " & Result); 

do tego:

Put(Number); Put(" x "); Put(Count); Put(" = "); Put(Result); New_Line; 

(normalnie nie byłoby umieścić wiele instrukcji w jednej linii, ale w tym przypadku ma to sens.)

Zauważ, że Integer'Image tworzy nieujemne liczby całkowite z spacją, coś, co zawsze uważałem za bardzo irytujące; Ada.Integer_Text_IO.Put nie robi tego (chyba, że ​​o to poprosisz).

Ty mógłby określają przeciążone "&" funkcje, mniej więcej tak:

function "&"(Left: String; Right: Integer) return String is 
begin 
    return Left & Integer'Image(Right); 
end "&"; 

function "&"(Left: Integer; Right: String) return String is 
begin 
    return Integer'Image(Left) & Right; 
end "&"; 

co uczyniłoby oryginalny Put_Line wezwanie ważne, ale wielokrotny Put połączenia są prawdopodobnie lepiej styl.

Answer 4

Opierając się na odpowiedź (i komentarz w innym pytaniu) od Keith Thompson, tutaj jest pełny program Ada, które mogą ciągi wyjściowe i całkowitymi z &, używając Put_Line, ale bez spacji że Integer'Image przeciwnym razie prepend:

with Ada.Text_IO; use Ada.Text_IO; 
with Ada.Integer_Text_IO; use Ada.Integer_Text_IO; 

procedure Main is 

function lstrip(S: String) return String is 
begin 
    if S(S'First) = ' ' then 
     return S(S'First+1 .. S'Last); 
    else 
     return S; 
    end if; 
end; 

function "&"(Left: String; Right: Integer) return String is 
begin 
    return Left & lstrip(Integer'Image(Right)); 
end "&"; 

function "&"(Left: Integer; Right: String) return String is 
begin 
    return lstrip(Integer'Image(Left)) & Right; 
end "&"; 

begin 
    Put_Line("x=" & 42); 
end Main;