as3 losowa tablica - randomize array - actionscript 3

Question

W jaki sposób losujesz tablicę za pomocą actionscript 3?

Answer 1

Jest krótka wersja użyciu Array.sort funkcji():

var arr : Array = [0,1,2,3,4,5,6,7,8,9]; 

function randomize (a : *, b : *) : int { 
    return (Math.random() > .5) ? 1 : -1; 
} 

trace(arr.sort(randomize)); 

Jeśli nie dostać "dość" przypadkowość Możesz sortować dwa razy :)

EDIT - wyjaśnienie linia po linii:

Dla Array metoda klasy sort() można przekazać nie tylko opcje sortowania, takie jak Array.CASEINSENSITIVE, Array.DESCENDING i tak dalej, ale także własne niestandardowe odniesienie do funkcji porównania (wywołanie zwrotne), które akceptuje dwa parametry (dwa elementy z tablicy do porównania). Z dokumentacji AS3:

Funkcja porównania powinna mieć dwa argumenty do porównania. Biorąc pod uwagę elementy A i B, wynik funkcji porównawczej może mieć wartość ujemną, 0 lub dodatnią:

• Negatywna wartość zwrotu określa, że ​​A pojawia się przed B w posortowanej kolejności.
• Zwracana wartość 0 określa, że ​​A i B mają tę samą kolejność sortowania.
• Dodatnia wartość zwracana określa, że ​​A pojawia się po B w posortowanej kolejności.

UWAGA: porównać parametry funkcyjne mogą być wpisane (jeśli tablica jest wpisany) i mieć dowolną nazwę np .:

function compareElements (elementA : SomeClass, elementB : SomeClass) : int; 

Metoda ta jest bardzo przydatna, gdy trzeba posortować tablicę elementy według ich specjalnych właściwości. W przypadku randomizacji compareFunction losowo zwraca -1, 0 lub 1 i sprawia, że ​​elementy tablicy zmieniają swoje miejsca (indeksy). Odkryłem, że lepsza randomizacja (w moim subiektywnym i matematycznie niesprawdzonym mniemaniu) jest kiedy metoda zwraca tylko -1 i 1. Należy również pamiętać o funkcji sortowania z niestandardową funkcją porównania doesn't compare elements sequentially, więc w niektórych szczególnych przypadkach wyniki randomizacji mogą się różnić od oczekiwanych.

Answer 2

Znalazłem to bardzo pomocne. Mam nadzieję, że to może ci pomóc.

// Array to Randomize 
var firstArray:Array = ["One","Two","Three","Four","Five","six","seven","eight","nine","ten"]; 
trace(firstArray); // Prints in order 

var newArray:Array = new Array(); 
function randomizeArray(array:Array):Array 
{ 
    var newArray:Array = new Array(); 

    while (array.length > 0) 
    { 
     newArray.push(array.splice(Math.floor(Math.random()*array.length), 1)); 
    } 

    return newArray; 
} 

var randomArray:Array = randomizeArray(firstArray); 
trace(randomArray); // Prints out randomized :) 

Answer 3

Nie ma lepszego sposobu, który pozwoli Ci losowo tablicę w miejscu, jeśli trzeba, że ​​i to nie będzie można utworzyć więcej niż jednej kopii oryginalnej tablicy.

package 
{ 
    import flash.display.Sprite; 

    public class RandomizeArrayExample extends Sprite 
    { 
     public function RandomizeArrayExample() 
     { 
      super(); 
      testDistribution(); 
     } 

     private function testDistribution():void 
     { 
      var hash:Object = { }; 
      var tester:Array = [1, 2, 3, 4]; 
      var key:String; 

      for (var i:int; i < 1e5; i++) 
      { 
       randomize(tester); 
       key = tester.join(""); 
       if (key in hash) hash[key]++; 
       else hash[key] = 1; 
      } 
      for (var p:String in hash) trace(p, "=>", hash[p]); 
     } 

     private function randomize(array:Array):Array 
     { 
      var temp:Object; 
      var tempOffset:int; 
      for (var i:int = array.length - 1; i >= 0; i--) 
      { 
       tempOffset = Math.random() * i; 
       temp = array[i]; 
       array[i] = array[tempOffset]; 
       array[tempOffset] = temp; 
      } 
      return array; 
     } 
    } 
} 

Answer 4

Miałem alternatywny wymóg, gdy chciałem losowo wstawić wiele tablic źródłowych do tablicy docelowej losowo. Podobnie jak Rytis, jestem wielkim fanem funkcji forEach, map i sort na Arrays.

var randomInsert:Function = function callback(item:*, index:int, array:Vector.<MyItem>):void 
{ 
    var j:Number = Math.floor(Math.random() * targetArray.length); 
    targetArray.splice(j,0,item);     
} 

targetArray = new Vector.<MyItem>(); 
sourceArray1.forEach(randomInsert, this); 
sourceArray2.forEach(randomInsert, this); 

Answer 5

Oto łatwiejsza funkcja. Działa również na wielowymiarowych tablicach

function randomizeArray(array:Array):Array 
{ 
    var newArray:Array = new Array(); 
    while (array.length > 0) 
    { 
     var mn=Math.floor(Math.random()*array.length) 
     newArray[newArray.length]=array[mn] 
     array.splice(mn,1) 
    } 
    return newArray; 
} 

Answer 6

Jeśli potrzebujesz tablicę być tasuje (Twoje elementy nie mogą się powtarzać).Można użyć tej funkcji:

/** 
* Shuffles array into new array with no repeating elements. Simple swap algorithm is used. 
*/ 
public function shuffleArray(original:Array):Array 
{ 
    // How many swaps we will do 
    // Increase this number for better results (more shuffled array, but slower performance) 
    const runs:int = original.length * 3; 
    var shuffled:Array = new Array(original.length); 

    var i:int; 
    var a:int; 
    var b:int; 
    var temp:Object; 

    // Copy original array to shuffled 
    for(i=0; i<shuffled.length; i++){ 
     shuffled[i] = original[i]; 
    } 

    // Run random swap cycle 'runs' times 
    for(i=0; i<runs; i++){ 
     // There is a chance that array element will swap with itself, 
     // and there is always small probability it will make your shuffle 
     // results not that good, hence try to experiment with 
     // different runs count as stated above 
     a = Math.floor(Math.random() * original.length); 
     b = Math.floor(Math.random() * original.length); 

     // Swap messages 
     temp = shuffled[a]; 
     shuffled[a] = shuffled[b]; 
     shuffled[b] = temp; 
    } 

    return shuffled; 
} 

Zastosowanie:

var testArray:Array = ["Water", "Fire", "Air", "Earth"]; 
trace(shuffleArray(testArray).concat()); 

Answer 7

to jak ja losowo moją tablicę 36 kart do gry pamięci

const QUANT_CARTAS: int = 36; 

//get the 36 numbers into the array 
for (var i: int = 0; i < QUANT_CARTAS; i++) 
{ 
    cartas.push(i); 
} 

//shuffles them =) 
for (var moeda: int = QUANT_CARTAS - 1; moeda > 0; moeda--) 
{ 
    var pos: int = Math.floor(Math.random() * moeda); 
    var carta: int = cartas[moeda]; 
    cartas[moeda] = cartas[pos]; 
    cartas[pos] = carta; 
} 
// and add them using the random order... 

    for (i = 0; i < QUANT_CARTAS; i++) 
{ 
    var novaCarta: Carta = new Carta(); 
    novaCarta.tipoCarta = cartas[i]; 
    etcetcetc............. 
} 

Answer 8

wybrać losowy ciąg znaków z tablicy

function keyGenerator(len:Number):String 
{ 
    function randomRange(minNum:Number, maxNum:Number):Number 
    { 
     return (Math.floor(Math.random() * (maxNum - minNum + 1)) + minNum); 
    } 
    var hexArray = ['0','1','2','3','4','5','6','7','8','9','A','B','C','D','E','F']; 
    var key = ""; 
    for (var i=0; i<len; i++) 
    { 
     key += hexArray[randomRange(0,hexArray.length-1)]; 
    } 
    return key; 
} 

Sposób użycia:

trace(keyGenerator(16));