Build doxygen ze skryptu CMake

Question

Znalazłem w sieci przykładowy plik cmake i umieściłem go w podkatalogu /doc mojego projektu, gdzie znajduje się również plik myproject.doxgen, zawierający konfigurację Doxygena.

Testowałem, że uruchomienie doxygen.exe myproject.doxygen daje prawidłowe wyniki. Muszę tylko zbudować to w procesie CMake. Więc /doc/CMakeLists.txt jest:

find_package(Doxygen) 
option(BUILD_DOCUMENTATION "Create and install the HTML based API   
documentation (requires Doxygen)" ${DOXYGEN_FOUND}) 

if(BUILD_DOCUMENTATION) 
    if(NOT DOXYGEN_FOUND) 
     message(FATAL_ERROR "Doxygen is needed to build the documentation.") 
    endif() 

    set(doxyfile_in ${CMAKE_CURRENT_SOURCE_DIR}/../doc/myproject.doxygen) 
    set(doxyfile ${CMAKE_CURRENT_BINARY_DIR}/doxyfile) 

    configure_file(${doxyfile_in} ${doxyfile} @ONLY) 

    message("Doxygen build started.") 

    add_custom_target(doc 
         COMMAND ${DOXYGEN_EXECUTABLE} ${doxyfile_in} 
         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/doc 
         COMMENT "Generating API documentation with Doxygen" 
         VERBATIM) 

    # install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/html DESTINATION  share/doc) 
endif() 

To nie działa dla mnie, to tylko kopiuje oryginalny plik konfiguracyjny do /build/my/project/doc/ i nie robi nic więcej.

To, czego chcę, to generowanie dokumentacji doxygen podczas moich kompilacji; idealnie, tylko podczas budowania konfiguracji Release.

Answer 1

Sposób, w jaki konfigurowany plik CMake jest skonfigurowany, tworzy cel o nazwie doc; budowanie tego celu (takiego jak uruchamianie make doc) generuje doxymentation. Cel nie jest częścią make all (lub odpowiednika); aby uczynić go takim, dodać ALL do tworzenia niestandardowych docelowej:

add_custom_target(
    doc ALL 
    COMMAND #... everything else as before 
) 

Jeśli chcesz ograniczyć ten cel zbudować tylko w konkretnej konfiguracji (jak już wspomniano w komentarzach), można użyć generator expressions:

add_custom_target(
    doc ALL 
    COMMAND $<$<CONFIG:Release>:${DOXYGEN_EXECUTABLE} ${doxyfile_in}> 
    WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/doc 
    COMMENT "Generating API documentation with Doxygen" 
    VERBATIM 
) 

Może się zdarzyć, że niektóre generatory CMake nie poradzą sobie dobrze z pustym COMMAND. Mając to na uwadze, następujące rozwiązania powinny być bezpieczne:

add_custom_target(
    doc ALL 
    COMMAND 
    $<$<CONFIG:Release>:${DOXYGEN_EXECUTABLE} ${doxyfile_in}> 
    $<$<NOT:$<CONFIG:Release>>:${CMAKE_COMMAND} -E echo "Only done in Release builds"> 
    WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/doc 
    COMMENT "Generating API documentation with Doxygen" 
    VERBATIM 
)