mogę używać zamknięcie na procedury obsługi zdarzeń (tj TButton OnClick)

Question

Jeśli próbuję użyć zamknięcia na obsługi zdarzeń kompilator narzeka:

niekompatybilnych typów: „Metoda wskaźnika i regularnej procedury”

które rozumiem .. ale czy istnieje sposób użycia clouser na wskaźniki metod? i jak określić, czy można?

np

Button1.Onclick = procedure(sender : tobject) begin ... end; 

Dzięki!

Answer 1

@Button1.OnClick := pPointer(Cardinal(pPointer(procedure (sender: tObject) 
begin 
    ((sender as TButton).Owner as TForm).Caption := 'Freedom to anonymous methods!' 

end)^) + $0C)^; 

works w Delphi 2010

Answer 2

Doskonałe pytanie.

O ile mi wiadomo, nie można tego zrobić w aktualnej wersji Delphi. Jest to bardzo niefortunne, ponieważ te anonimowe procedury byłyby wspaniałe do szybkiego skonfigurowania obsługi zdarzeń obiektu, na przykład podczas konfigurowania urządzeń testowych w strukturze automatycznego testowania xUnit.

Nie powinno być dwa sposoby na CodeGear do wdrożenia tej funkcji:

1: Zezwalaj na tworzenie metod anonimowych. Coś takiego:

Button1.OnClick := procedure(sender : tobject) of object begin 
    ... 
end; 

Problem polega na tym, co należy umieścić jako wskaźnik dla metody anonimowej. Można użyć wskaźnika własnego obiektu, z którego została utworzona anonimowa metoda, ale można tworzyć tylko anonimowe metody z kontekstu obiektu. Lepszym pomysłem może być po prostu stworzenie obojętnego obiektu za kulisami, aby zawierał anonimową metodę.

2: Alternatywnie, można pozwolić typom zdarzeń na akceptowanie zarówno metod, jak i procedur, o ile mają one wspólny podpis. W ten sposób możesz stworzyć obsługę zdarzeń tak, jak chcesz:

Button1.OnClick := procedure(sender : tobject) begin 
    ... 
end; 

W moich oczach jest to najlepsze rozwiązanie.

Answer 3

W poprzednich wersjach Delphi można użyć zwykłej procedury jak obsługi zdarzeń dodając ukryty wskaźnik samodzielne parametrów i ciężko typecast go:

procedure MyFakeMethod(_self: pointer; _Sender: TObject); 
begin 
    // do not access _self here! It is not valid 
    ... 
end; 

... 

var 
    Meth: TMethod; 
begin 
    Meth.Data := nil; 
    Meth.Code := @MyFakeMethod; 
    Button1.OnClick := TNotifyEvent(Meth); 
end; 

nie jestem pewien wyżej naprawdę kompiluje ale powinno dać masz ogólny pomysł. Zrobiłem to wcześniej i zadziałało to w przypadku regularnych procedur. Ponieważ nie wiem, jaki kod generuje kompilator dla zamknięć, nie mogę powiedzieć, czy to zadziała.

Answer 4

Jej łatwo rozszerzyć poniżej obsłużyć więcej typów zdarzeń formularza.

Wykorzystanie

procedure TForm36.Button2Click(Sender: TObject); 
var 
    Win: TForm; 
begin 
    Win:= TForm.Create(Self); 
    Win.OnClick:= TEventComponent.NotifyEvent(Win, procedure begin ShowMessage('Hello'); Win.Free; end); 
    Win.Show; 
end; 

Kod

unit AnonEvents; 

interface 
uses 
    SysUtils, Classes; 

type 
    TEventComponent = class(TComponent) 
    protected 
    FAnon: TProc; 
    procedure Notify(Sender: TObject); 
    class function MakeComponent(const AOwner: TComponent; const AProc: TProc): TEventComponent; 
    public 
    class function NotifyEvent(const AOwner: TComponent; const AProc: TProc): TNotifyEvent; 
    end; 

implementation 

{ TEventComponent } 

class function TEventComponent.MakeComponent(const AOwner: TComponent; 
    const AProc: TProc): TEventComponent; 
begin 
    Result:= TEventComponent.Create(AOwner); 
    Result.FAnon:= AProc; 
end; 

procedure TEventComponent.Notify(Sender: TObject); 
begin 
    FAnon(); 
end; 

class function TEventComponent.NotifyEvent(const AOwner: TComponent; 
    const AProc: TProc): TNotifyEvent; 
begin 
    Result:= MakeComponent(AOwner, AProc).Notify; 
end; 

end.